• 윈도우 XP 사용자는 IE80Blocker.cmd 를 실행하시면, .cmd 명령을 통해 레지스트리에 IE8 설치를 제한하는 명령이 입력됩니다.
  

• 아래에서 보시는 것처럼, cmd 상태에서 /u 옵션을 입력을 해야 정상적으로 실행됩니다.
  

• 아래는 IE80Blocker.cmd 내용입니다.
  

set ProductName=Internet Explorer 8
set REGBlockKey=HKLM\SOFTWARE\Microsoft\Internet Explorer\Setup\8.0
set REGBlockValue=DoNotAllowIE80

set RemoteMachine=%1

if ""=="%1" goto Usage
if "/?"=="%1" goto Usage
if /I "/H"=="%1" goto Usage
if /I "/B"=="%1" goto LocalMachine
if /I "/U"=="%1" goto LocalMachine
set RemoteMachineName=%1
set Action=%2

:Parse
if /I "/B" == "%Action%" goto Block
if /I "/U" == "%Action%" goto UnBlock
goto Usage

:Block
Echo Blocking deployment of %ProductName% on %RemoteMachineName%
REG ADD "\\%RemoteMachine%\%REGBlockKey%" /v %REGBlockValue% /t REG_DWORD /d 1 /f
goto End
rem 위의 내용이 IE8의 자동업데이트를 차단하는 레지스트리 추가부분 입니다.

:UnBlock
Echo Unblocking deployment of %ProductName% on %RemoteMachineName%
REG DELETE "\\%RemoteMachine%\%REGBlockKey%" /v %REGBlockValue% /f
goto End
rem 위의 내용이 IE8의 자동업데이트 차단을 해제하는 레지스트리 부분입니다.

:LocalMachine
echo LOCAL!
set Action=%1
set RemoteMachine=.
set RemoteMachineName=the local machine
goto Parse

:Usage
Echo.
Echo This tool can be used to remotely block or unblock the delivery of
Echo %ProductName% via Automatic Updates.
Echo.
Echo ------------------------------------------------------------
Echo Usage:
Echo %0 [machine name] [/B] [/U] [/H]
REM [machine name] [/B|U|H]
Echo B = Block %ProductName% deployment
Echo U = Allow %ProductName% deployment
Echo H = Help
Echo.
Echo To block or unblock installation on the local machine use
Echo period ("." with no quotes) as the machine name
Echo.
Echo Examples:
Echo %0 mymachine /B (blocks delivery on machine "mymachine")
Echo.
Echo %0 /U (unblocks delivery on the local machine)
Echo ------------------------------------------------------------
Echo.

:End